// Persistence Of Vision raytracer version 3.1 sample file.
//
// Participating media environment with spotlights.
//

//
// The camera.
//

camera {
  location <10, 6, -20>
  look_at <0, 4, 0>
}
  
media {  
  //emission rgb<0,.01,0> 
  //absorption rgb<0,0,0.1>
  scattering { 
       1, // isotropic
       rgb 0.03
  }  
}    
  
// Light source not interacting with the atmosphere. 
light_source { <0, 15, 0> color rgb 0.7
  media_interaction off   
  shadowless 
}
 /* */ 
// Spotlights pointing at ball. 
light_source { 
  <-10, 15, -5> 
  color rgb<1, .3, .3> * 2
  spotlight
  point_at <0, 5, 0>   
  
  // These control the way that light tapers off at the edges of the cone
  radius 10      // default 30
  falloff 15     // default  45
  tightness 1    // default 0    
  
  media_attenuation on
}
  
// Room 
box { <-20, 0, -20>, <20, 20, 20>
  pigment { rgb 1 }
  finish { ambient 0.2 diffuse 0.5 }
  hollow
}  

// Ball. 
sphere { <0, 5, 0>, 1
  pigment { rgb 1 }
  finish { ambient 0.3 diffuse 0.7 phong 1 }
}