#include "colors.inc"
background{White}   

camera {
    location <0, 11, -14>
    look_at <0, 4, 0>
}  
  
  
light_source {<20, 20, -20> color 2*White }      


#declare cup = lathe {
    cubic_spline  
    13,
    <0  , 0.0>,   
    <2.5, 0.0>,
    <2.5, 0.5>,
    <0.5, 0.6>, 
    <0.5, 3.5>,
    <2.0, 4.5>, 
    <3.0, 6.5>, 
    <3.0, 8.0>, 
    <2.5, 8.0>, 
    <2.5, 6.5>, 
    <1.8, 5.0>, 
    <0.0, 4.0>,
    <0.0, 4.0>     
    pigment { rgb <.4,.3,1> }  
    finish { ambient .3}
}




plane {
  y, 
  0.0 
  pigment { color rgb <.5,1,.2> }
}


// scale along x
#macro myMatScaleX(s)
     matrix  < s, 0, 0,
               0, 1, 0,
               0, 0, 1,
               0, 0, 0> 
#end 

// shear along y and z, proportional to x
#macro myMatShear(s)
     matrix  < 1, s, s,
               0, 1, 0,
               0, 0, 1,
               0, 0, 0> 
#end  

// shear along x proportional to y+z,  and tranlate along x
#macro myMatShearTrans(sh, tr)
     matrix  < 1, 0, 0,
               sh, 1, 0,
               sh, 0, 1,
               tr, 0, 0> 
#end  
         
#declare Count=-2;
 #while (Count < 3)    
  object{
      cup 
      myMatShearTrans(.3*Count, Count)
  }
  #declare Count=Count+1;
#end